#!/usr/bin/env perl
# Convert my Openbox 2 menu file to Openbox 3 format. (I hate editing XML by
# hand.)
use strict;

my $home = $ENV{"HOME"};

sub read_line () {
	my $line = <F>;
	return [] unless defined $line;
	chomp $line;
	return [] if $line eq "";
	$line =~ s/^\s*\[([^\]]*)\]\s*// or die "No command on '$line'\n";
	my $command = $1;
	$line =~ s/^\(([^\)]*)\)\s*// or return [$command];
	my $first = $1;
	$line =~ s/^{([^}]*)}// or return [$command, $first];
	return [$command, $first, $1];
}

open F, "<$home/.openbox/menu" or die "Can't open ob2 menu file\n";
my %menus = ();
my $id = 0;
my @stack = ();
my $menu = undef;
while (my @line = @{read_line()}) {
	my $c = $line[0];
	if (($c eq "begin") or ($c eq "submenu")) {
		push @stack, [$menu, $line[1]];
		$menu = [];
	} elsif ($c eq "end") {
		my $n;
		my ($omenu, $title) = @{pop @stack};
		if (!defined $omenu) {
			$n = "root-menu";
		} else {
 			$n = "menu" . ($id++);
		}
		# Don't bother with empty menus -- they're probably styles
		# lists.
		my $isempty = (scalar(@$menu) == 0);
		unshift @$menu, "<menu id=\"$n\" label=\"$title\">\n";
		push @$menu, "</menu>\n";
		$menus{$n} = $menu unless $isempty;
		last unless defined $omenu;
		$menu = $omenu;
		push @$menu, "<menu id=\"$n\" />\n" unless $isempty;
	} elsif ($c eq "exec") {
		push @$menu, "<item label=\"$line[1]\"><action name=\"Execute\"><execute>$line[2]</execute></action></item>\n";
	} elsif ($c eq "workspaces") {
		push @$menu, "<menu id=\"client-list-menu\" />\n";
	} elsif ($c eq "config") {
		push @$menu, "<item label=\"ObConf\"><action name=\"Execute\"><execute>obconf</execute></action></item>\n";
	} elsif ($c eq "stylesdir") {
		# No equivalent.
	} elsif ($c eq "reconfig") {
		push @$menu, "<item label=\"$line[1]\"><action name=\"Reconfigure\" /></item>\n";
	} elsif ($c eq "restart") {
		# No equivalent.
	} elsif ($c eq "exit") {
		push @$menu, "<item label=\"$line[1]\"><action name=\"Exit\" /></item>\n";
	} else {
		die "Unknown command $c\n";
	}
}
close F;

open OUT, ">$home/.config/openbox/menu.xml" or die "can't open output";
print OUT <<EOF;
<?xml version="1.0" encoding="UTF-8"?>

<openbox_menu xmlns="http://openbox.org/"
        xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
        xsi:schemaLocation="http://openbox.org/
                file:///opt/share/openbox/menu.xsd">
EOF

# We have to do this because OB3 isn't clever enough to deal with using a menu
# before it's been defined.
sub num ($) {
	my ($id) = @_;
	$id =~ /(\d+)$/ or return -1;
	return int($1);
}
foreach my $id (sort { num($b) <=> num($a) } keys %menus) {
	print OUT join "", @{$menus{$id}};
}

print OUT <<EOF;
</openbox_menu>
EOF